pro sdwparams_Event, Event

common sdwp, maskImage, maskExtension, maskButtons, goodMaskValue, browseMask
common sdwsave1, maskfile, maskext, maskeori, maskgoodval
 
  widget_control,Event.Id,get_uvalue=Ev
 
  case Ev of
 
  'ok': begin
    ; Go update the parameter file on disk.
    openw, olun, 'sdw_savepar.pro', /GET_LUN
    printf, olun,'pro sdw_savepar'
    printf, olun, $
	'common sdwsave1, maskfile, maskext, maskeori, maskgoodval'
    printf, olun, "maskfile = '",maskfile,"'"
    printf, olun, "maskext = '",maskext,"'"
    printf, olun, 'maskeori = ',maskeori
    printf, olun, 'maskgoodval = ',maskgoodval
    printf, olun,''
    printf, olun,'end'
    close, olun
    free_lun,olun
    widget_control, event.top, /destroy
    end
  'mb': begin
    val = event.value
    maskeori = val
    if (event.value eq 0) then begin
      WIDGET_CONTROL,maskImage, SENSITIVE=0
      WIDGET_CONTROL,maskExtension, SENSITIVE=1
    endif else begin
      WIDGET_CONTROL,maskImage, SENSITIVE=1
      WIDGET_CONTROL,maskExtension, SENSITIVE=0
    endelse
    end
  
  'mi': begin
    widget_control,maskImage,get_value=temp
    maskfile = temp(0)
    end

  'me': begin
    widget_control,maskExtension,get_value=temp
    maskext = temp(0)
    end

  'gmv': begin
    widget_control,goodMaskValue,get_value=maskgoodval
    end

  'bm': begin
      tempfile = pickfile(/read)
      test = findfile (tempfile, COUNT = fcount)
      if (strlen(tempfile) gt 0 and fcount ne 0) then begin
        maskfile = tempfile
        WIDGET_CONTROL, maskImage, set_value = maskfile
      endif else begin
        if (fcount eq 0) then begin
          nosuchfile,tempfile
        endif
      endelse
    end

  endcase

end


pro sdw_parameters, group=Group

common sdwp, maskImage, maskExtension, maskButtons, goodMaskValue, browseMask
common sdwsave1, maskfile, maskext, maskeori, maskgoodval

  if n_elements(Group) eq 0 then group=0
  sdwparams = widget_base (group_leader=Group, column=1, $
			   xoffset=300, yoffset=300, map=1)
  maskButtons = cw_bgroup (sdwparams,['image extension','separate image'], $
			   uvalue='mb', frame=1, row = 1, $
			   set_value = maskeori, /exclusive)
  mim = widget_base(sdwparams, title='mask image base', /row)
  maskImage = cw_field (mim, title = 'Mask Image:', value = maskfile, $
			uvalue = 'mi', xsize = 40, /all_events)
  browseMask = widget_button(mim,uvalue='bm', value='Browse')
  maskExtension = cw_field (sdwparams, title = 'Mask Image Extension:', $
			    value = maskext, uvalue = 'me', xsize = 10, $
			    /all_events)
  goodMaskValue = cw_field (sdwparams, title = 'Mask good value:', $
			    value = maskgoodval, uvalue = 'gmv', xsize = 5, $
			    /all_events, /integer)


  okbutton = widget_button (sdwparams, uvalue='ok', value='OK', xsize=150)

  if (maskeori eq 0) then begin
    WIDGET_CONTROL,maskImage, SENSITIVE=0
    WIDGET_CONTROL,maskExtension, SENSITIVE=1
  endif else begin
    WIDGET_CONTROL,maskImage, SENSITIVE=1
    WIDGET_CONTROL,maskExtension, SENSITIVE=0
  endelse

  widget_control, sdwparams, /realize
  xmanager, 'sdwparams', sdwparams, /modal
end